How to add a block volume to a template

Attach a block volume to an instance that a template provisions, format it on first boot, and record the mount in /etc/fstab so the filesystem mounts after a reboot. This guide extends templates without persistent data disks, such as simple-vm.

These templates provide reference implementations:

• wordpress-mysql: mounts /dev/sdb at /var/lib/mysql for MySQL data
• self-managed-postgres: mounts /dev/sdb at /var/lib/postgresql for PostgreSQL data
• dev-environment: uses a block volume to back a shared NFS export

Reference pattern from existing templates#

The wordpress-mysql template declares a block volume, an attachment to the MySQL instance, and a cloud-init script that formats and mounts the disk:

resource "openstack_blockstorage_volume_v3" "mysql_data" {
  name = "${local.name_prefix}-mysql-data"
  size = var.db_volume_size
}

resource "openstack_compute_volume_attach_v2" "mysql_data" {
  instance_id = openstack_compute_instance_v2.mysql.id
  volume_id   = openstack_blockstorage_volume_v3.mysql_data.id
}

The mount logic lives in cloud-init/mysql.yaml:

#cloud-config
runcmd:
  - |
    set -e
    DEV=/dev/sdb
    for i in $(seq 1 30); do [ -b "$DEV" ] && break; sleep 5; done
    if ! blkid "$DEV" >/dev/null 2>&1; then mkfs.ext4 -F "$DEV"; fi
    mkdir -p /var/lib/mysql
    mount "$DEV" /var/lib/mysql
    grep -q "$DEV" /etc/fstab || echo "$DEV /var/lib/mysql ext4 defaults,nofail 0 2" >> /etc/fstab

On Quake AI, the boot volume occupies the first SCSI device. The first attached data volume appears as /dev/sdb, which is the path used by the templates in this repository.

Add volume resources to your template#

The following example extends simple-vm. Adjust resource names and the mount path for your workload.

1. Declare variables#

Add to variables.tf:

variable "data_volume_size" {
  description = "Size in GB for the attached data volume"
  type        = number
  default     = 20
}

variable "data_mount_path" {
  description = "Filesystem path where the data volume is mounted"
  type        = string
  default     = "/mnt/data"
}

2. Create the volume and attachment#

Add to main.tf (or a new storage.tf):

resource "openstack_blockstorage_volume_v3" "data" {
  name = "${var.instance_name}-data"
  size = var.data_volume_size
}

resource "openstack_compute_volume_attach_v2" "data" {
  instance_id = openstack_compute_instance_v2.vm.id
  volume_id   = openstack_blockstorage_volume_v3.data.id
}

Place the attachment after the instance resource so OpenTofu can resolve openstack_compute_instance_v2.vm.id.

3. Mount the volume on first boot#

Create cloud-init/data-volume.yaml:

#cloud-config
runcmd:
  - |
    set -e
    DEV=/dev/sdb
    MOUNT=${mount_path}
    for i in $(seq 1 30); do [ -b "$DEV" ] && break; sleep 5; done
    if ! blkid "$DEV" >/dev/null 2>&1; then mkfs.ext4 -F "$DEV"; fi
    mkdir -p "$MOUNT"
    mount "$DEV" "$MOUNT"
    grep -q "$DEV" /etc/fstab || echo "$DEV $MOUNT ext4 defaults,nofail 0 2" >> /etc/fstab

Wire it into the instance. If the instance has no existing user_data, add:

resource "openstack_compute_instance_v2" "vm" {
  # ... existing arguments ...

  user_data = templatefile("${path.module}/cloud-init/data-volume.yaml", {
    mount_path = var.data_mount_path
  })
}

Plan and apply#

From the template directory:

tofu plan
tofu apply

The plan shows one new openstack_blockstorage_volume_v3 and one openstack_compute_volume_attach_v2. It also shows an instance replacement when you add user_data for the first time.

Verify the attachment and mount#

See also#

• Create and attach a block volume: step-by-step tutorial for volumes outside IaC
• wordpress-mysql template: production volume + MySQL mount pattern
• self-managed-postgres template: PostgreSQL data volume pattern
• dev-environment template: shared volume with NFS export
• How to customize a template's image and flavor: resize compute without adding storage
• Block storage how-to guides: create, extend, and snapshot volumes through the Console and CLI